Matematicamente

# Conchiglia.
# Script addattato da:
# http://ayapin.film.s.dendai.ac.jp/~matuda/Gnuplot/pm3d.html
#
cot(x)=1/tan(x)
x(u,v)=D*(A*sin(b)*cos(u)+R*cos(v+phi)*cos(u+W)-R*sin(m)*sin(v+phi)*sin(u+W))*exp(u*cot(a))
y(u,v)=(-A*sin(b)*sin(u)-R*cos(v+phi)*sin(u+W)-R*sin(m)*sin(v+phi)*cos(u+W))*exp(u*cot(a))
z(u,v)=(-A*cos(b)+R*sin(v+phi)*cos(m))*exp(u*cot(a))
D=1;a=4*pi/9;b=2*pi/9;phi=11*pi/36;m=pi/18;W=pi/6;A=25;R=16
L=300
set xrange[-L+50:L+50]
set yrange[-L:L]
set zrange[-1.5*L:0.5*L]
set pm3d explicit
set palette rgb 8,7,27
unset colorbox
set parametric
set hidden3d
set ticslevel 0
set size square
set view 65,30,2.4,1
set vrange[0:2*pi]
unset key
unset border
unset xtics
unset ytics
unset ztics
set isosamples 96,24
set urange[-2*pi:4*pi]
set terminal jpeg medium size 480,480
set output "conchiglia.jpeg"
set multiplot
splot x(u,v),y(u,v),z(u,v) w pm3d
splot x(u,v),y(u,v),z(u,v) lt 5
unset multiplot
set output

Scrivi Commento

Si prega di scrivere solo commenti che riguardano questo articolo. La redazione pubblicherà solo i messaggi che saranno ritenuti idonei. I messaggi compariranno, mediamente, il giorno seguente, dopo che la redazione li ha approvati.
Nome:
Commento:
Codice:*	Inserireilcodiceaumentatoditredecine

Powered by AkoComment Tweaked Special Edition v.1.4.6
AkoComment © Copyright 2004 by Arthur Konze - www.mamboportal.com
All right reserved